参照元†
返り値†
- 下記のように大きく分かれます。
- レジスタをスタックに保存する部分
- システムコール番号を取得する部分
- システムコールのコードにジャンプする部分
レジスタをスタックに保存する部分†
.align 5
ENTRY(vector_swi)
sub sp, sp, #S_FRAME_SIZE
stmia sp, {r0 - r12} @ Calling r0 - r12
ARM( add r8, sp, #S_PC )
ARM( stmdb r8, {sp, lr}^ ) @ Calling sp, lr
THUMB( mov r8, sp )
THUMB( store_user_sp_lr r8, r10, S_SP ) @ calling sp, lr
mrs r8, spsr @ called from non-FIQ mode, so ok.
str lr, [sp, #S_PC] @ Save calling PC
str r8, [sp, #S_PSR] @ Save CPSR
str r0, [sp, #S_OLD_R0] @ Save OLD_R0
zero_fp
システムコール番号を取得する部分†
/*
* Get the system call number.
*/
#if defined(CONFIG_OABI_COMPAT)
- 古い ABI をサポートする場合。
呼び出すべきシステムコールは swi の引数で指定される。
/*
* If we have CONFIG_OABI_COMPAT then we need to look at the swi
* value to determine if it is an EABI or an old ABI call.
*/
#ifdef CONFIG_ARM_THUMB
tst r8, #PSR_T_BIT
movne r10, #0 @ no thumb OABI emulation
ldreq r10, [lr, #-4] @ get SWI instruction
- tst: ユーザモードが Thumb モードで実行されているか検査する。
- r8 は spsr のコピーが入っている。
- spsr は ユーザ側の CPSR の値がコピーされているレジスタ。
- movne: ARM モードなら r10 を 0 クリアする。
- ne は Not Equal つまり、Thumb モードではない、ということ。
- ldrne: ARM モードなら r10 に、
ユーザが実行した swi 命令コードをロードする。
- swi 命令発行時、lr に swi 命令の「次」の命令のアドレスが入る。
そのため swi 命令の位置は lr - 4 になる。
#else
- ユーザコードで Thumb モードを使わない場合。
ldr r10, [lr, #-4] @ get SWI instruction
A710( and ip, r10, #0x0f000000 @ check for SWI )
A710( teq ip, #0x0f000000 )
A710( bne .Larm710bug )
- ldr: r10 に、ユーザが実行した swi 命令コードをロードする。
- swi 命令発行時、lr に swi 命令の「次」の命令のアドレスが入る。
そのため swi 命令の位置は lr - 4 になる。
- and: 0x0f000000 でマスクする。
- teq: マスクした値が 0x0f000000 かどうか？
- bne: swi 命令でなければ、.Larm710bug にジャンプする。
#endif
#ifdef CONFIG_CPU_ENDIAN_BE8
rev r10, r10 @ little endian instruction
- rev: メモリからロードした swi 命令の並びを逆にする。
- 常に 0 ビット側に swi 命令の即値が来るようにしている。
#endif
#elif defined(CONFIG_AEABI)
- 新 ABI を使う場合。
呼び出すべきシステムコールは r7 で指定される。
/*
* Pure EABI user space always put syscall number into scno (r7).
*/
A710( ldr ip, [lr, #-4] @ get SWI instruction )
A710( and ip, ip, #0x0f000000 @ check for SWI )
A710( teq ip, #0x0f000000 )
A710( bne .Larm710bug )
#elif defined(CONFIG_ARM_THUMB)
/* Legacy ABI only, possibly thumb mode. */
tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
ldreq scno, [lr, #-4]
#else
/* Legacy ABI only. */
ldr scno, [lr, #-4] @ get SWI instruction
A710( and ip, scno, #0x0f000000 @ check for SWI )
A710( teq ip, #0x0f000000 )
A710( bne .Larm710bug )
#endif
#ifdef CONFIG_ALIGNMENT_TRAP
ldr ip, __cr_alignment
ldr ip, [ip]
mcr p15, 0, ip, c1, c0 @ update control register
#endif
enable_irq
システムコールのコードにジャンプする部分†
get_thread_info tsk
adr tbl, sys_call_table @ load syscall table pointer
ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing
- tbl は r8 の別名
- tsk は r9 の別名
#if defined(CONFIG_OABI_COMPAT)
/*
* If the swi argument is zero, this is an EABI call and we do nothing.
*
* If this is an old ABI call, get the syscall number into scno and
* get the old ABI syscall table address.
*/
bics r10, r10, #0xff000000
eorne scno, r10, #__NR_OABI_SYSCALL_BASE
ldrne tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
bic scno, scno, #0xff000000 @ mask off SWI op-code
eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
#endif
stmdb sp!, {r4, r5} @ push fifth and sixth args
tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
bne __sys_trace
cmp scno, #NR_syscalls @ check upper syscall limit
adr lr, BSYM(ret_fast_syscall) @ return address
ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
add r1, sp, #S_OFF
2: mov why, #0 @ no longer a real syscall
cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
bcs arm_syscall
b sys_ni_syscall @ not private func
ENDPROC(vector_swi)
コメント†
![[PukiWiki]](image/pukiwiki.png "[PukiWiki]")
